提供几个关于采集的函数(ASP)

<%
''''''''''''''''断剑注释'''''''''''''''''''''''''
''''strText为要切取内容的那段打的内容''''''''''''
''''strStarTag为要切取内容的开始的地方''''''''''
''''strEndTag为要切取内容的结束的地方''''''''''
''''GetText返回值为切取出来的内容''''''''''''''
'''''''''''''''注释结束''''''''''''''''''''''''
Function GetText(strText, strStartTag, strEndTag)
dim intStart
intStart = instr(strText, strStartTag)
if intStart then
intStart = intStart + len(strStartTag)
intEnd = InStr(intStart, strText, strEndTag)
GetText = Mid(strText, intStart, intEnd - intStart)
else
GetText = " "
end if
End Function

%>
<%
'''''''''断剑注释''''''''''''
'''''''''以下的函数都可以不管'''''''''
''''''''只管入口函数getHTTPPage'''''''
''''''''path为要读取的网页地址''''''''
''''''''getHTTPPage返回读取到的网页内容''
''''''''这里应该注意的是gb2312这里,如果被读取的网页编码是
''gb2312就用gb2312,如果是UTF-8的话,就换成UTF-8''''
''''''''注释结束''''''''''
Function getHTTPPage(Path)
t = GetBody(Path)
getHTTPPage=BytesToBstr(t,"gb2312")
End function

Function GetBody(url)
on error resume next
Set Retrieval = CreateObject("Microsoft.XMLHTTP")
With Retrieval
.Open "get", url, False, "", ""
.Send
GetBody = .ResponseBody
End With
Set Retrieval = Nothing
End Function
Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
set objstream = nothing
End Function
%>